Вы можете включать код, который будет выполняться, только если соблюдено некоторое условие (или наоборот, если не соблюдено). Вот для чего нужны условные выражения.

Выражение if — первая часть условного выражения. Оно объявляет условие, которое должно быть истинным, чтобы последующий код был выполнен. Be careful, you need TWO EQUALS when comparing values! (That's because one equal is for declaring values!)

ZenScript
 Copy
val test = 0;

if (test == 0) { //true
    print("Test is zero!");
}

Выражение else может быть добавлено после условного выражения, чтобы объявить, что должно быть выполнено, если выражение из if ложно.

ZenScript
 Copy
var test = 0;

if (test == 0) { //true
    //will be executed when test is equal to 0
    print("Test is zero!");
} else {
    //will be executed when test is not equal to 0
    print("Test is NOT zero!");
}

test = 1;
if (test == 0) { //false
    //will be executed when test is equal to 0
    print("Now, test is zero!");
} else {
    //will be executed when test is not equal to 0
    print("Now, test is NOT zero!");
}

Supported Calculations are +,-,*,/,mod,concatenation(~)

Supported Operands are Logical OR(||), Logical AND(&&), Bitwise OR(|), Bitwise AND(&), and Bitwise XOR(^)

ZenScript
 Copy
//You can check for:


//Number values
val a = 0 as int;
if (a == 0) { print("NumVal"); }

//Calculated number values
val b = 1;
val c = 5;
//All evaluate to true
if (b+c == 6) { print("Num1!"); }
if (b*c == 5) { print("Num2!"); }
if (b/c == 0.2) { print("Num3!"); }

//OR, XOR, AND
val d = "Hello";
val e = "World";
val f = d~e; //f = "HelloWorld", the Tilde just concatenates one thing to another

//||(OR) means, as long as one of the criteria is met, it evaluates to true
if (d == "Hello" || e == "Hello") { print("OR1!"); }        //true
if (d == "Hello" || e == "World") { print("OR2!"); }        //true

//^(XOR) means, ONLY ONE criteria may be met, otherwise it evaluates to false
if (d == "Hello" ^ e == "Hello") { print("XOR1!"); }        //true
if (d == "Hello" ^ e == "World") { print("XOR2!"); }        //false

//&&(AND) means, both criteria need to be met, otherwise it evaluates to false
if (d == "Hello" && e == "Hello") { print("AND1!"); }       //false
if (d == "Hello" && e == "World") { print("AND2!"); }       //true

Surely, always typing out an if/else structure can be annoying. Especially if you just want to do an either or condition. That's why the ? operator was implemented. It follows the same logic as an if/else statement, it only is by far less code required. Syntax: boolean ? if : else

ZenScript
 Copy
val switchy = false;

//prints switchy state
print("Switchy is " ~ switchy);

//if switchy is true, vInt = 1, otherwise vInt = 2
val vInt = switchy ? 1 : 2;
print(vInt);

//Prints "Hello" if switchy is stue, otherwise prints "Bye"
print(switchy ? "Hello" : "Bye");

//Prints "Bye" if switchy is true, otherwise prints "Hello"
switchy ? print("Bye") : print("Hello");

Вы можете использовать следующие операторы. Все приведенные примеры истинны.

Название	символ	Объяснение	Пример
Название Не	символ !	Объяснение Инвертирует логическое значение	Пример !false
Название Не равно	символ !=	Объяснение Проверяет, что значение перед знаком и после него не равны	Пример ! != 2
Название Равно	символ ==	Объяснение Проверяет, что значение перед знаком и после равны	Пример 1 == 1
Название Больше	символ >	Объяснение Проверят, что значение перед знаком больше, чем то, что после	Пример 1 > 2
Название Больше или равно	символ >=	Объяснение Проверят, что значение перед знаком больше или равно тому, что после	Пример 1 >= 1
Название Lesser than	символ <	Объяснение Проверяет, что значение перед знаком меньше, чем то, что после	Пример 1 < 2
Название Меньше или равно	символ <=	Объяснение Проверяет, что значение перед знаком меньше или равно тому, что после	Пример 1 <= 1
Название Logical AND	символ &&	Объяснение Checks if both before and after values are true, false if one or both are false	Пример true && true
Название Logical OR	символ ||	Объяснение Checks if either the value before or after are true, false if neither are true	Пример false || true
Название Bitwise XOR	символ ^	Объяснение Checks if exactly one of the before or after values is true, false if both or none are true	Пример true ^ false
Название Bitwise AND	символ &	Объяснение Performs a bitwise AND operation on the before and after values. See this for more	Пример true && true
Название Bitwise OR	символ |	Объяснение Performs a bitwise OR operation on the before and after values. See this for more	Пример false || true

The main difference between the single and the double, with semantics aside, is that the double performs a check after each condition and exits early - this is called short-circuiting. However, the single goes through the entire chain of conditions, even if the first one would have cancelled the entire condition. This not only saves resources, but also allows for easier scripting such as null checks and chained conditions.

ZenScript
 Copy
var a = 5;
var item = ... as IItemStack;

// Even though a is 5, it still goes through all of the conditions listed
if (a == 5 | a == 3 | a == 10 | a == -1) {
    ...
}

// Even though a is 5 and the condition is impossible (a variable can't be both 3 and 5), it still goes through all of the conditions listed
if (a == 3 & a < 2 & a > 8 & a == 5) {
    ... 
}

// Checks if item is not null before accessing variables from item
if (!isNull(item) && item.amount == 1) {
    ...
}

// Checks if item is not null while accessing variables from a potentially null item, throwing an error if the item is null
if (!isNull(item) & item.amount == 1) {
    ...
}

The in and the has operator check if something is in something.
First you need the list you want to check in, then the in/has then the value you want to check for. in and has are the same keyword for ZS, but in most cases people use has for checking if a collection contains an item and in for loops as this represents the English grammar.

You can check, if a mod is loaded by checking if it's in the loadedMods list

ZenScript
 Copy
//While contains checks can use in
if (loadedMods in "mcp") {
    print("Minecraft Coder Pack loaded");
}

//Most people prefer using has
if (loadedMods has "mcp") {
    print("Minecraft Coder Pack loaded");
}

You can also check if an item matches a definition by comparing two IIngredients.
With this one you need to be a bit careful as not to confuse the two entries:
This is only true when the IIngredient AFTER the in can also be found completely in the one BEFORE the in.
In most cases you will use the has keyword instead as it's intention is more clear and it does exactly the same.

ZenScript
 Copy
// Checks if the iron ingot is in the oreDict "ingotIron"
if (<ore:ingotIron> in <minecraft:iron_ingot>) {
    print("Iron ingots are in the right oreDict");
}

// Preferred, same function as previous
if (<ore:ingotIron> has <minecraft:iron_ingot>) { 
    print("Iron ingots are in the right oreDict");
}

This is only true when ALL matching items from the IIngredient AFTER the has can also be found in the IIngredient BEFORE has: Say we have an IIngredient that contains all dusts (e.g. redstone and glowstone dust):

ZenScript
 Copy
val redstone = <minecraft:redstone>;
val glowstone = <minecraft:glowstone>;
val allDusts = <ore:dustAll>;
allDusts.add(redstone, glowstone);

//True as redstone is a part of alldusts
if (allDusts has redstone) {

}

//False as allDusts consists of redstone and glowstone, and redstone only consists of redstone.
if (redstone has allDusts) {

}