Менеджеры рецептов

Name: getRecipeByName

Этот метод получает рецепт по имени и возвращает объект Recipe.

ZenScript
 Copy
getRecipeByName(String name);

Можно применить его, чтобы получить ингредиенты рецепта и вывести commandString для каждого из них.

ZenScript
 Copy
for ingredient in craftingTable.getRecipeByName("minecraft:arrow").ingredients {
    println(ingredient.commandString);
}

Name: getRecipesByOutput

Этот метод получает список рецептов на основании его выхода и возвращает список объектов Recipe.

ZenScript
 Copy
getRecipesByOutput(IIngredient name);

Можно использовать этот метод, чтобы получить ингредиенты всех рецептов с данным выходом и вывести commandString для каждого.

ZenScript
 Copy
for recipe in craftingTable.getRecipesByOutput(<item:minecraft:stick>) {
    println("> " + recipe.id);
    for ingredient in recipe.ingredients {
        println(ingredient.commandString);
    }
}

Name: getAllRecipes

Этот метод получает список всех рецептов для данного менеджера рецептов и возвращает список объектов Recipe.

ZenScript
 Copy
getAllRecipes();

Можно использовать этот метод, чтобы получить ингредиенты всех рецептов и вывести commandString для каждого:

ZenScript
 Copy
for recipe in furnace.getAllRecipes() {
    println("> " + recipe.id);
    for ingredient in recipe.ingredients {
        println(ingredient.commandString);
    }
}

Name: remove

Позволяет удалять рецепты из менеджера рецепта по выходному предмету.

ZenScript
 Copy
remove(IItemStack output);

Пример использования — удаление рецепта палки в верстаке.

ZenScript
 Copy
craftingTable.remove(<item:minecraft:stick>);

Еще пример — удаление выплавки алмаза из алмазной руды в печи:

ZenScript
 Copy
furnace.remove(<item:minecraft:diamond>);

Name: removeByName

Позволяет удалять рецепты из менеджера рецептов по имени рецепта.

ZenScript
 Copy
removeByName(String name);

Пример использования — удаление рецепта стрелы в верстаке:

ZenScript
 Copy
craftingTable.removeByName("minecraft:arrow");

Name: removeByModid

This method allows you to remove recipes from this Recipe Manager based on the the recipe name's modid.
There is an optional parameter that is used to exclude recipes from being removed.
Note: The name given to the RecipeFilter is just the path of the recipe id.
For example, if the recipe id is minecraft:orange_wool, the name given will be orange_wool. Еще пример — ID рецепта id_мода:путь/имя, именем будет только часть путь/имя.

ZenScript
 Copy
removeByModid(String modid);

или

removeByModid(String modid, RecipeFilter exclude);

Пример использования — удаление всех рецептов из верстака на minecraft:

ZenScript
 Copy
craftingTable.removeByModid("minecraft");

Еще пример — удаление всех рецептов на minecraft кроме рецепта оранжевой шерсти.

ZenScript
 Copy
craftingTable.removeByModid("minecraft", (name as string) => {
    return name == "orange_wool";
});

Name: removeByRegex

Позволяет удалять рецепты из менеджера рецептов, проверяя ID рецепта по регулярному выражению.

ZenScript
 Copy
removeByRegex(String regex);

Пример использования — удаление всех рецептов, ID которых соответствует шаблону .*wool.* (то есть, все, которые содержат wool где угодно в названии).

ZenScript
 Copy
craftingTable.removeByRegex(".*wool.*");

Name: removeAll

Позволяет удалять все рецепты из менеджера рецептов.

ZenScript
 Copy
removeAll(String regex);

Пример — удаление всех рецептов в плавильной печи.

ZenScript
 Copy
blastFurnace.removeAll();